root/projects/appendruncntltofile/trunk/defn/ApplicationEnginePrograms/GS/GS_REN_REPT/GS_REN_REPT.MAIN.GBL.default.1900-01-01.Step02.OnExecute.pcdefn.peoplecode

/* ************************************************** */
/* Prototype code to rename reports to be picked up   */
/* by a 3rd party report scheduler                    */
/* Copyright 2010 -  Grey Sparling Solutions          */
/*-----------------------------------------------------/
/* This program works under the following assumptions */
/* - It runs on a windows process scheduler           */
/* - The machine running this program will have the   */
/*   following                                        */
/*   o Access to the files stored across servers      */
/*     running the reports                            */
/*   o The paths of the shared reports are the same   */
/*     regardless of the server that ran the report   */
/* ************************************************** */
Function GetLastInstanceProcessed() Returns number;
   
   Local number &RetValue;
   
   SQLExec("SELECT MAX(PRCSINSTANCE) FROM PS_GS_LASTPRCS", &RetValue);
   Warning ("Processing output with Process Instance Greater than " | &RetValue);
   
   Return &RetValue;
   
End-Function;

Function UpdateGetLastInstanceProcessed(&nInstanceToUpdate As number);
   
   Local Record &recLastPrcs = CreateRecord(Record.GS_LASTPRCS);
   &recLastPrcs.GetField(Field.PRCSINSTANCE).Value = &nInstanceToUpdate;
   If &recLastPrcs.Save() Then
      Warning ("Updated max process instance to be " | &nInstanceToUpdate);
   Else
      Error ("Could not update max process instance to be " | &nInstanceToUpdate);
   End-If;
   
End-Function;

Function RenameFile(&sOldFileName As string, &sNewFileName As string);
   
   rem This function calls the windows rename function to update the file name;
   Local string &sDir = GetEnv("PS_SERVDIR");
   Local number &RetCode;
   
   If FileExists(&sOldFileName, %FilePath_Absolute) Then
      Warning ("Executing --> rename " | Char(34) | &sOldFileName | Char(34) | " " | Char(34) | &sNewFileName | Char(34));
      &RetCode = Exec("cmd.exe /c rename " | Char(34) | &sOldFileName | Char(34) | " " | Char(34) | &sNewFileName | Char(34), %Exec_Synchronous + %FilePath_Absolute);
      Warning ("Return Code = " | &RetCode);
   Else
      Warning ("Could not find file to rename: " | &sOldFileName);
   End-If;
End-Function;

Function GetOldFileName(&nPrcsInstance As number, &sParmList As string) Returns string;
   
   Local string &RetValue = "";
   Local number &nLocFilePath;
   Local number &nLocEndOfPath;
   
   rem find the output file name by searching for command line parm;
   &nLocFilePath = Find("-OP", &sParmList) + 4;
   If &nLocFilePath > 4 Then
      rem Find the end of the current parameter;
      &nLocEndOfPath = Find(" -", &sParmList, &nLocFilePath);
      If &nLocEndOfPath = 0 Then
         &nLocEndOfPath = Len(&sParmList);
      End-If;
      rem Return the string from starting position to ending position;
      &RetValue = RTrim(Substring(&sParmList, &nLocFilePath, &nLocEndOfPath - &nLocFilePath));
   End-If;
   
   Return &RetValue;
   
End-Function;

Function getNewFileName(&nInstance As number, &sOldFilePath As string) Returns string;
   
   Local string &sOldFile;
   Local string &sRunCntlId;
   Local string &RetValue = "";
   Local array of string &sPathSegments;
   
   &sPathSegments = Split(&sOldFilePath, "\");
   If &sPathSegments.Len = 0 Then
      &sPathSegments = Split(&sOldFilePath, "/");
   End-If;
   
   &sOldFile = &sPathSegments [&sPathSegments.Len];
   
   If All(&sOldFile) Then
      
      rem get run control ID for current process instance;
      SQLExec("SELECT RUNCNTLID FROM PSPRCSRQST WHERE PRCSINSTANCE = :1", &nInstance, &sRunCntlId);
      
      rem Concatenate run control ID at the proper place;
      If Substring(&sOldFile, Len(&sOldFile) - 3, 1) = "." Then
         &RetValue = Left(&sOldFile, Len(&sOldFile) - 4) | "-" | RTrim(&sRunCntlId) | Right(&sOldFile, 4);
      Else
         &RetValue = RTrim(&sOldFile) | "-" | RTrim(&sRunCntlId);
      End-If;
   End-If;
   
   Return &RetValue;
   
End-Function;

Local number &nPrcsInstance;
Local string &sParameter;
Local string &sStartingFileName;
Local string &sNewFileName;
Local number &nMaxPrcsInstance;
Local number &nStartingInstance = GetLastInstanceProcessed();

REM Get List of Reports Recently Processed ;
Local SQL &sqlPrcsParms = CreateSQL("select PRCSINSTANCE, PARMLIST from PSPRCSPARMS WHERE PRCSINSTANCE > :1", &nStartingInstance);
While &sqlPrcsParms.Fetch(&nPrcsInstance, &sParameter)
   
   &sStartingFileName = GetOldFileName(&nPrcsInstance, &sParameter);
   
   If All(&sStartingFileName) Then
      
      &sNewFileName = getNewFileName(&nPrcsInstance, &sStartingFileName);
      
      RenameFile(&sStartingFileName, &sNewFileName);
   Else
      Warning ("No Output File found for Process Instance " | &nPrcsInstance);
   End-If;
   
   &nMaxPrcsInstance = &nPrcsInstance;
   
End-While;

UpdateGetLastInstanceProcessed(&nMaxPrcsInstance);

&sqlPrcsParms.Close();