root/projects/drilltojournalcf/trunk/defn/Records/FU/FUNCLIB_GSDRILL/GS_DRILL_WRK/FieldFormula.pcdefn.peoplecode

Declare Function adjust_line_scroll PeopleCode FUNCLIB_GL.JOURNAL_LINE FieldFormula;

Function ApplyDrillCriteria()
   
   /* Grey Sparling - Code to drill to row with chartfield values passed in as a parameter */
   Local Rowset &RS_CFS = GetRowset(Scroll.BU_LED_CF_VW);
   Local string &sChartField;
   Local number &sNumParameters = 0;
   Local boolean &PassedParameters = False;
   Local array of string &CF_Params;
   Local array of string &CF_ParamValues;
   Local number &m;
   
   &CF_Params = CreateArray(&sChartField);
   &CF_ParamValues = CreateArray(&sChartField);
   
   /* Grey Sparling - Build Array with all the parameters passed in the Request Object */
   
   For &l = 1 To &RS_CFS.ActiveRowCount;
      
      &sChartField = &RS_CFS(&l).BU_LED_CF_VW.CHARTFIELD.Value;
      &CF_ParamValues [&sNumParameters + 1] = %Request.GetParameter(&sChartField);
      
      If All(&CF_ParamValues [&sNumParameters + 1]) Then
         
         &CF_Params [&sNumParameters + 1] = &sChartField;
         &PassedParameters = True;
         &sNumParameters = &sNumParameters + 1;
         
      End-If;
   End-For;
   
   /* Grey Sparling - Use the parameters in the array to find the appropriate set of Journal Lines */
   
   If &PassedParameters Then
      If JRNL_HEADER.JRNL_HDR_STATUS = "D" Or
            JRNL_HEADER.JRNL_HDR_STATUS = "P" Or
            JRNL_HEADER.JRNL_HDR_STATUS = "U" Then
         /* Grey Sparling - Journal is read only */
         
         /* Grey Sparing - Loop through parameters array and set them in work record for searching */
         
         For &m = 1 To &sNumParameters;
            @("JRNL_PANELS_WRK." | &CF_Params [&m]) = &CF_ParamValues [&m];
         End-For;
         
         REM What does this function do? ;
         adjust_line_scroll();
      Else
         /* Grey Sparling - Journal is editable */
         Local Rowset &rsJrnlLines = GetLevel0().GetRow(1).GetRowset(Scroll.JRNL_LN);
         Local number &j;
         
         For &j = 1 To &rsJrnlLines.ActiveRowCount
            Local Row &rowTest = &rsJrnlLines.GetRow(&j);
            &sFoundCombination = True;
            
            /* Grey Sparling - Loop through fields in array to see if current row matches all passed parameters */
            
            For &m = 1 To &sNumParameters;
               If &rowTest.GetRecord(Record.JRNL_LN).GetField(@("Field." | &CF_Params [&m])).Value = &CF_ParamValues [&m] Then
                  &rowTest.GetRecord(Record.JRNL_LN).GetField(@("Field." | &CF_Params [&m])).SetCursorPos(%Page);
               Else
                  &sFoundCombination = False;
               End-If;
               
            End-For;
            
            If &sFoundCombination Then
               Break;
            End-If;
            
         End-For;
      End-If;
   End-If;
   
End-Function;