root/projects/updatetreeeffdtinqry/trunk/defn/ApplicationEnginePrograms/GS/GS_QRYEFFDT/GS_QRYEFFDT.MAIN.GBL.default.1900-01-01.Step01.OnExecute.pcdefn.peoplecode

Function ReturnNewTreeCrit(&InTreeCrit As string) Returns string
   
   Local array of string &TreeCritSegments;
   Local string &NewEffDt;
   Local number &k;
   Local string &NewTreeCrit;
   
   &TreeCritSegments = Split(&InTreeCrit, ",");
   
   SQLExec("select max(a.effdt) from pstreedefn a where a.setid = :1 and a.setcntrlvalue = :2 and a.tree_name = :3 and a.effdt <= %currentdatein", &TreeCritSegments [1], &TreeCritSegments [2], &TreeCritSegments [3], &NewEffDt);
   
   For &k = 1 To &TreeCritSegments.Len
      
      If &k > 1 Then
         If &k = 4 Then
            &NewTreeCrit = &NewTreeCrit | "," | &NewEffDt;
         Else
            &NewTreeCrit = &NewTreeCrit | "," | &TreeCritSegments [&k];
         End-If;
      Else
         &NewTreeCrit = &TreeCritSegments [&k];
      End-If;
   End-For;
   
   Return &NewTreeCrit;
   
End-Function;

Function ProcessCriterion(&CriteriaObj As ApiObject, &j As number)
   
   Local string &NewTreeCrit;
   
   If &CriteriaObj.expr1type = 2 Then
      rem Field criteria;
      If &CriteriaObj.expr1field.name = Field.DEPTID Then
         Warning ("Criterion Field #" | &j | " = " | &CriteriaObj.expr1field.name);
         If &CriteriaObj.operator = %Query_CondInTree Then
            Warning ("In Tree Criteria exists");
            Warning (&CriteriaObj.expr2constant1);
            &NewTreeCrit = ReturnNewTreeCrit(&CriteriaObj.expr2constant1);
            Warning ("Updating new Tree Criterion = " | &NewTreeCrit);
            &CriteriaObj.expr2constant1 = &NewTreeCrit;
         Else
            Warning ("Other type of Criteria");
         End-If;
      End-If;
   End-If;
   
End-Function;

Local ApiObject &MyQuery, &MySession, &CriteriaCollection;
Local ApiObject &CurrentCriteria;
Local string &QryToProcess;
Local number &i;

&MySession = %Session;

If &MySession <> Null Then
   
   &MyQuery = &MySession.getquery();
   
   Local SQL &sqlGetQueries = CreateSQL("select QRYNAME from PSQRYDEFN where QRYNAME like 'GS%'");
   While &sqlGetQueries.Fetch(&QryToProcess)
      
      &MyQuery.open(&QryToProcess, True, True);
      
      Warning ("Just Opened Query " | &MyQuery.name | ", " | &MyQuery.description);
      
      &CriteriaCollection = &MyQuery.queryselect.criteria;
      
      For &i = 1 To &CriteriaCollection.count;
         
         ProcessCriterion(&CriteriaCollection.item(&i), &i);
         
      End-For;
      
      &MyQuery.save();
      &MyQuery.close();
      
   End-While;
   
End-If;